[архив] Скрипты Inno Setup. Помощь и советы [часть 2]

Raf-9600 · Отправлено: **20:02, 24-11-2009** | #**481**

Ктонить может объединить эти коды?

Запрет установки в папку Windows

Описания компонентов

Сколько есть, и требуеться для установки

Слайд-шоу рандомно (в окне инсталляции)

Улучшенный деинсталлятор

Реализация рисунка 497х58 в верху инсталлятора

serg aka lain · Отправлено: **20:08, 24-11-2009** | #**482**

Цитата A1EXXX:

создавать файл каждый раз вручную надоедает »

Ну, можно положить в установочный пакет готовый "desktop.ini",
насколько мне извесно, винде не важно точное расположение иконки в папке
(Serega, думаю меня поправит, или опровергнет), посему его можно заполнить сразу, и добавить в пакет установки.

Код:

[.ShellClassInfo]
IconResource=MyProg.exe
IconIndex=0

и использовать такой код:

Или вариант без таскания за собой готового desktop.ini, создать его во время установки:

A1EXXX · Отправлено: **20:22, 24-11-2009** | #**483**

serg aka lain, первый код я вроде как пометил "альтернативкой", т.е. использование готового Desktop.ini (ну или создавать и подключать через [Files]). А второй код как раз оно

Но меня больше интересует избавление от ewWaitUntilTerminated в скрипте FreeArc...

Raf-9600, а ISS Joiner'ом не пробовал??

Raf-9600 · Отправлено: **20:32, 24-11-2009** | #**484**

A1EXXX, Пробовал - некатит.

serg aka lain · Отправлено: **20:37, 24-11-2009** | #**485**

Цитата A1EXXX:

А второй код как раз оно »

Ну, хоть это радует.

Цитата:

меня больше интересует избавление от ewWaitUntilTerminated в скрипте FreeArc...

Понятия не имею, но, думаю придёт Serega, и обязательно поможет.

Serega · Конфигурация компьютера

Цитата A1EXXX:

не знаю, как применить это в моём случае... »

Вы какую версию Inno используете? Дело в том, что для обычной версии (пробовал на 5.3.5 ansi) не получается, в момент установки вылетает ошибка, а для Restools - без проблем...

Цитата A1EXXX:

но создавать файл каждый раз вручную надоедает »

Все скрипты приходится писать руками...

Цитата serg aka lain:

винде не важно точное расположение иконки в папке »

Только если она расположена в корне самой папки, а не её подпапках.

Цитата serg aka lain:

Serega, думаю меня поправит »

Всё правильно, я в своё время использовал все эти методы...

A1EXXX · Отправлено: **21:23, 24-11-2009** | #**487**

Serega, у меня последняя от Restools. Для моего случая нужно использовать весь пример скрипта или этого куска достаточно?

Цитата:

[code]
var
ResultCode: Integer;

function IsProgRunning(ProgName: string): Boolean;
// функция определяет, запущенно ли приложение
var
Size: Integer;
begin
Result:= False;
Exec('cmd', '/c tasklist /fi "IMAGENAME eq ' + ProgName + '" >"' +
ExpandConstant('{tmp}\RunList"'), '', SW_HIDE, ewWaitUntilTerminated, ResultCode);
if FileSize(ExpandConstant('{tmp}\RunList'), Size) then
if Size > 0 then Result:= True;
end;

если достаточно, то как задать задержку 200-300 мс и связать с arc.exe моего скрипта...

Serega · Конфигурация компьютера

Цитата A1EXXX:

у меня последняя от Restools. »

Написал на основе .dll'ки, т.к. при частом запуске cmd для проверки процесса, не всегда удаётся нажать на кнопку Отмена в момент распаковки.

Пример

Код:

#define MyAppName "Test"
#define MyAppVerName "Test"
#define MyAppExeName "Test.exe"

[Setup]
AppName={#MyAppName}
AppVerName={#MyAppName}
DefaultDirName={pf}\{#MyAppName}
DirExistsWarning=no
;DisableReadyPage=true
ShowLanguageDialog=auto
OutputBaseFilename=setup
OutputDir=.
UninstallDisplayIcon={app}\{#MyAppExeName}
DefaultGroupName={#MyAppName}
InternalCompressLevel=none
Compression=none

[UninstallDelete]
Name: {app}; Type: filesandordirs

[Languages]
Name: eng; MessagesFile: compiler:Default.isl
Name: rus; MessagesFile: compiler:Languages\Russian.isl

[Files]
; измените на своё место расположение dll'ки, у меня она расположена
; C:\Program Files\Inno Setup 5\Libraries\*
Source: C:\Program Files\Inno Setup 5\Libraries\ISTask.dll; Flags: dontcopy
Source: C:\Program Files\FreeArc\bin\Arc.exe; Flags: dontcopy

[CustomMessages]
ExtrError=Произошла ошибка во время извлечения данных. Установка будет прервана.

[Code]
function RunTaskA(FileName: string; bFullpath: Boolean): Boolean;
  external 'RunTask@files:ISTask.dll stdcall delayload setuponly';
function KillTaskA(ExeFileName: string): Integer;
  external 'KillTask@files:ISTask.dll stdcall delayload setuponly';

// запускает указанный файл, с параметрами указанными в CmdShow
function WinExec(lpCmdLine: PChar; uCmdShow: Cardinal): Cardinal;
  external 'WinExec@kernel32.dll stdcall';

var
  SecondProgressBar: TNewProgressBar;
  ExtractAllArc: Boolean;

procedure InitializeWizard();
begin
  WizardForm.FileNameLabel.Hide;
  WizardForm.StatusLabel.Top:=ScaleY(81);
  WizardForm.StatusLabel.Width:=WizardForm.InnerNotebook.Width;
  WizardForm.StatusLabel.Width:=ScaleX(262);
  WizardForm.ProgressGauge.Top:=ScaleY(100);
  WizardForm.ProgressGauge.Left:=ScaleX(155);
  WizardForm.ProgressGauge.Width:=ScaleX(262);

  SecondProgressBar := TNewProgressBar.Create(WizardForm);
  with SecondProgressBar do
    begin
      Parent := WizardForm.InstallingPage;
      Left := ScaleX(0);
      Top := ScaleY(100);
      Width := ScaleX(150);
      Height := ScaleY(21);
      Min := 0;
      Max := 13; //задается как (кол-во распаковываемых архивов * 3) + 1
    end;
end;

procedure WaitProgUntilTerminated;
var
  i: Integer;
begin
  // проверим запустился ли файл, если нет, то
  if not RunTaskA('Arc.exe', False) then
   for i:= 0 to 500 do
    // подождём пока файл запустится
    if not RunTaskA('Arc.exe', False) then
      begin
        Sleep(10); // ждём максимум 5 сек.
        Application.ProcessMessages;
      end
    else Break;
  // если запущен, то ждём завершения
  while RunTaskA('Arc.exe', False) do
    begin
      Sleep(10);
      Application.ProcessMessages;
    end;
end;

procedure PlsInsertNextDisk(num: Integer; CheckedFile: string);
var
  Capt: string;
begin
  CheckedFile:= ExpandConstant(CheckedFile);
  if not FileExists(CheckedFile) then
    begin
      Capt:= 'Пожалуйста, вставьте диск %n, содержащий файл %f и нажмите ОК для продолжения установки.';
      StringChange(Capt, '%n', inttostr(num));
      StringChange(Capt, '%f', ExtractFileName(CheckedFile));
      MsgBox(Capt, mbInformation, MB_OK);
      PlsInsertNextDisk(num, CheckedFile);
    end;
end;

procedure ExtractArc(arcArchName, arcDestDir:string);
var
  ResultCode: Integer;
begin
  WizardForm.StatusLabel.Caption:= SetupMessage(msgStatusExtractFiles);
  // запускаем файл
  ResultCode:= WinExec(AddQuotes(ExpandConstant('{tmp}\arc.exe')) + ' x ' +
    AddQuotes(ExpandConstant(arcArchName)) + ' -y -dp' +
      AddQuotes(ExpandConstant(arcDestDir)), SW_HIDE);

  if (ResultCode < 33) then
    begin
      MsgBox(ExpandConstant('{cm:ExtrError}'), mbCriticalError, MB_OK);
      SecondProgressBar.Hide;
      if RunTaskA('Arc.exe', False) then KillTaskA('Arc.exe');
      DelTree(ExpandConstant('{app}'), True, True, True);
      Abort;
    end
  else
    begin
      SecondProgressBar.Position:= SecondProgressBar.Position + 3;
      WaitProgUntilTerminated;
    end;
end;

procedure CurStepChanged(CurStep: TSetupStep);
begin
  if CurStep = ssInstall then
    begin
      WizardForm.StatusLabel.Caption:= SetupMessage(msgStatusExtractFiles);
      ExtractTemporaryFile('arc.exe');
      SecondProgressBar.Position:= SecondProgressBar.Position + 1;

      ExtractArc('{src}\Project.arc','{app}');
      ExtractArc('{src}\data-2.arc','{app}');

      PlsInsertNextDisk(2, '{src}\data-3.arc'); //если data4.arc не найден в корне диска, просим второй диск
      ExtractArc('{src}\data-3.arc','{app}');
      ExtractArc('{src}\data-4.arc','{app}');
      PlsInsertNextDisk(1, '{src}\data-1.arc'); //снова просим первый диск

      ExtractAllArc:= True; // сообщим, что все архивы распаковали
    end;
end;

procedure CancelButtonClick(CurPageID: Integer; var Cancel, Confirm: Boolean);
begin
  if CurPageID = wpInstalling then
    if ExtractAllArc then
      Cancel:= True
    else
    if ExitSetupMsgBox then
      begin
        if RunTaskA('Arc.exe', False) then KillTaskA('Arc.exe');
        DelTree(ExpandConstant('{app}'), True, True, True);
        KillTaskA(ChangeFileExt(ExtractFileName(ParamStr(0)), '.tmp'));
      end
    else
  Cancel:= False;
end;

A1EXXX · Отправлено: **22:42, 24-11-2009** | #**489**

Serega,

, огромное спасибо!

Мегареспект!!!

JohnDes · Отправлено: **23:45, 24-11-2009** | #**490**

Добрые и знающие люди помогите пожалуйста.
Напишите скрипт в котором осуществляется проверка ип адресса компьютера и если он есть в списке, установка закрывается с ошибкой "Вам запрещено устанавливать данный продукт"
Ип чтобы был на подобии 192.168.11.22.
И их могло быть несколько. И чтобы была кнопка обратиться к администрации (кнопка вела на сайт).
Помогите пожалуйста.
Или вообще такое возможно ?