Opera - это браузер, быстрый и удобный.
Обладает рядом
уникальных функций:
читать дальше »
Opera Unite - простые в использовании приложения для обмена данными с другими пользователями.
Opera Turbo - компрессия входящего траффика на серверах компании Opera
Визуальные вкладки - эскизы страниц в панели вкладок.
Настраиваемая Экспресс-панель - визуальные закладки, отображаемые при каждом открытии новой вкладки.
Opera Link - синхронизация Экспресс-панели, закладок, заметок и других важных данных.
Сеансы - удобная штука, можно наоткрывать группу сайтов, объединённых общей тематикой, сохранить их как сеанс и переключаться между сеансами.
Проверка орфографии, расширенный набор горячих клавиш, вкладки, много всего. Я пользуюсь именно этим браузером.
Домашняя страница: http://www.opera.com/
Русскоязычное сообщество: http://operafan.net/
Описание формата конфигурационных файлов:
http://www.opera.com/support/usingopera/operaini/
Тихая установка:
читать дальше »
- Запускаем оперу до первого диалогового окна. В нем выбираем русский язык.
- Ждем следующее окно:
- Из временной папки системы забираем Opera installer.msi и 1049.mst
- Запускаем батником
Код:
msiexec.exe /i Opera installer.msi /qb SET_DEFAULT_BROWSER=1 ALLUSERS=1 CREATE_DESKTOP_ICON_REG_USR=1 CREATE_QUICKLAUNCH_ICON_REG_USR=1 CREATE_STARTMENU_ICONS_REG_USR=1 MULTI_USER_SETTING=1 TRANSFORMS=1049.MST
ALLUSERS - для всех пользователей
CREATE_DESKTOP_ICON_REG_USR- ярлык на рабочем столе
CREATE_QUICKLAUNCH_ICON_REG_USR - ярлык в быстром запуске
CREATE_STARTMENU_ICONS_REG_USR - ярлык в меню пуск
MULTI_USER_SETTING - отдельные настройки для каждого пользователя
SET_DEFAULT_BROWSER - установить браузером по умолчанию
Установка в нестандартную папку - просто добавьте INSTALLDIR к опциям установщика, например, так:
Код:
msiexec /i "opera installer.msi" /qb INSTALLDIR=D:\Opera10 ALLUSERS=1 CREATE_DESKTOP_ICON=1 CREATE_QUICKLAUNCH_ICON=1 CREATE_STARTMENU_ICONS=1 MULTI_USER_SETTING=1 TRANSFORMS=1049.MST
Изменение параметров по умолчанию. Для этого вам придется сгенерировать файл настроек оперы. Это обычный ини-файл, его можно создавать даже командным файлом. Следующий пример меняет шкуру оперы по умолчанию на шкуру vista_skin-5_2.zip
читать дальше »
Код:
@Echo Off
SetLocal EnableExtensions DisableDelayedExpansion
cd /d %~dp0
msiexec /i "opera installer.msi" /qb ALLUSERS=1 CREATE_DESKTOP_ICON=1 CREATE_QUICKLAUNCH_ICON=1 CREATE_STARTMENU_ICONS=1 MULTI_USER_SETTING=1 TRANSFORMS=1049.MST INSTALLDIR=D:\Opera10
copy vista_skin-5_2.zip d:\opera10\skin\vista_skin-5_2.zip
md "%appdata%\opera\opera10"
set configfile="%appdata%\opera\opera10\operaprefs.ini"
echo [User Prefs] >> %configfile%
echo Button Set={Resources}skin\vista_skin-5_2.zip >>%configfile%
NSIS-скрипт, который я использую для автоматической установки Opera, flash player и скинов браузера, сразу и одним нажатием:
читать дальше »
Код:
!define PRODUCT_NAME "Opera"
!define PRODUCT_VERSION "10.54"
!define pkgdir "d:\package"
!include "MUI.nsh"
SetCompressor /SOLID lzma
!define MUI_ABORTWARNING
!define MUI_ICON "${NSISDIR}\Contrib\Graphics\Icons\modern-install.ico"
!define MUI_COMPONENTSPAGE_SMALLDESC
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH
!insertmacro MUI_LANGUAGE "Russian"
!define BRANDING "http://www.winreview.ru"
InstType "Полная"
InstType "Сокращенная"
InstType "Минимальная"
Var gMode
Var IniFile
Var WindowCaption
Var Skins
Var Flash
Var Opera
Var MultiUsers
Var Desk
Var QL
Var SM
Var Def
!include "WordFunc.nsh"
!include "FileFunc.nsh"
Function .onInit
;
; when /g switch specified and not present /s switch, then generate default config
;
;inifile definition
;
StrCpy $Opera 0
StrCpy $Flash 0
StrCpy $Skins 0
StrCpy $MultiUsers 0
StrCpy $Desk 0
StrCpy $QL 0
StrCpy $SM 0
StrCpy $WindowCaption "Установка ${PRODUCT_NAME} ${PRODUCT_VERSION}"
${WordReplace} "$EXEFILE" ".exe" ".ini" "+" $IniFile
StrCpy $IniFile "$EXEDIR\$IniFile"
;gMode detection
StrCpy $gMode 0
${GetOptions} $CMDLINE "/G" $0
IfErrors EndFunc
IfSilent +4 0
StrCpy $gMode 1
Delete $IniFile
StrCpy $WindowCaption "Генератор файла ответов ${PRODUCT_NAME}"
EndFunc:
FunctionEnd
!macro ProcessSection secID
;
;if gMode=1 - generate default config. if 0 and not silent - reads the config
StrCpy $R0 1
StrCmp $gMode 1 WriteMode
IfSilent 0 EndMarco
IfFileExists $IniFile 0 EndMarco
ReadINIStr $R0 $IniFile Sections ${secID}
IfErrors 0 +2
StrCpy $R0 0
Goto EndMarco
WriteMode:
StrCpy $R0 0
WriteINIStr $IniFile Sections ${secID} 1
EndMarco:
!macroend
Name "${PRODUCT_NAME}"
Caption "$WindowCaption"
OutFile "${PRODUCT_NAME}-${PRODUCT_VERSION}.exe"
InstallDir "$PROGRAMFILES\${PRODUCT_NAME}"
ShowInstDetails show
BrandingText "${BRANDING}"
Section "!${PRODUCT_NAME}" secOPERA
SectionIn 1 2 3 RO
!insertmacro ProcessSection "secOPERA"
StrCmp $gMode 1 SectionEnd1
StrCpy $Opera 1
SectionEnd1:
SectionEnd
Section "Многопользовательский режим работы" secMultiUsers
SectionIn 1 2 3
!insertmacro ProcessSection "secMultiUsers"
StrCmp $gMode 1 EndSection
StrCpy $MultiUsers 1
EndSection:
SectionEnd
Section "Сделать браузером по умолчанию" secDef
SectionIn 1 2 3
!insertmacro ProcessSection "secDef"
StrCmp $gMode 1 EndSection
StrCpy $Def 1
EndSection:
SectionEnd
SectionGroup /e "Ярлыки"
Section "Меню пуск" secSM
SectionIn 1 2 3
!insertmacro ProcessSection "secSM"
StrCmp $gMode 1 EndSection
StrCpy $SM 1
EndSection:
SectionEnd
Section "Рабочий стол" secDesk
SectionIn 1 2
!insertmacro ProcessSection "secDesk"
StrCmp $gMode 1 EndSection
StrCpy $Desk 1
EndSection:
SectionEnd
Section "Панель быстрого запуска" secQL
SectionIn 1 2
!insertmacro ProcessSection "secQL"
StrCmp $gMode 1 EndSection
StrCpy $QL 1
EndSection:
SectionEnd
SectionGroupEnd
SectionGroup /e "Дополнительные компоненты"
Section "Flash player for Opera" secFlash
SectionIn 1 2
!insertmacro ProcessSection "secFlash"
StrCmp $R0 0 EndSection 0
StrCpy $Flash 1
EndSection:
SectionEnd
Section "Обложки интерфейса" secSkins
SectionIn 1
!insertmacro ProcessSection "secSkins"
StrCmp $R0 0 EndSection 0
StrCpy $Skins 1
EndSection:
SectionEnd
SectionGroupEnd
Section -Post
StrCmp $Opera 0 SkipOpera
SetOutPath "$TEMP"
File "${pkgdir}\opera\1049.MST"
File "${pkgdir}\opera\opera installer.msi"
ExecWait "msiexec.exe /i $\"$TEMP\opera installer.msi$\" /qb SET_DEFAULT_BROWSER=$Def ALLUSERS=1 CREATE_DESKTOP_ICON_REG_USR=$Desk CREATE_QUICKLAUNCH_ICON_REG_USR=$QL CREATE_STARTMENU_ICONS_REG_USR=$SM MULTI_USER_SETTING=$MultiUsers TRANSFORMS=$\"$TEMP\1049.MST$\""
Delete "$TEMP\opera installer.msi"
Delete "$TEMP\1049.MST"
SkipOpera:
StrCmp $Flash 0 SkipFlash
SetOutPath "$TEMP"
File "${pkgdir}\opera\install_flash_player.exe"
ExecWait "$TEMP\install_flash_player.exe -install"
Delete "$TEMP\install_flash_player.exe"
SkipFlash:
StrCmp $Skins 0 SkipSkins
SetOutPath "$INSTDIR\Skin"
File "${pkgdir}\opera\*.zip"
SkipSkins:
SectionEnd
LangString DESC_OPERA ${LANG_RUSSIAN} "Браузер ${PRODUCT_NAME} ${PRODUCT_VERSION}"
LangString DESC_FLASH ${LANG_RUSSIAN} "Компонент Flash Player для просмотра Flash-анимаций в Opera"
LangString DESC_SKINS ${LANG_RUSSIAN} "Дополнительные скины для изменения внешнего вида браузера"
LangString DESC_MULTIUSERS ${LANG_RUSSIAN} "Отдельный профиль настроек для каждого пользователя"
!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
!insertmacro MUI_DESCRIPTION_TEXT ${secOPERA} $(DESC_OPERA)
!insertmacro MUI_DESCRIPTION_TEXT ${secFlash} $(DESC_FLASH)
!insertmacro MUI_DESCRIPTION_TEXT ${secSkins} $(DESC_SKINS)
!insertmacro MUI_DESCRIPTION_TEXT ${secMultiUsers} $(DESC_MULTIUSERS)
!insertmacro MUI_FUNCTION_DESCRIPTION_END
Как работает этот скрипт, можно почитать
здесь и
здесь
Последняя версия скрипта снабжена генератором файла ответов, полное
описание генератора здесь.
Описание дистрибутива
Целью создания данного дистрибутива была реализация возможности его тихой установки, для этого была система создания инсталляторов NSIS. Скопилированный дистрибутив поддерживает следующие ключи:
Код:
Opera-10.51.exe /S
Производит тихую установку бразуера, скинов и флэш-плеера, если в папке, откуда производится запуск инсталлятора, нет файла ответов Opera-10.51.ini.
Код:
Opera-10.51.exe /G
Производит запуск инсталлятора в режиме генератора ответов. Вы можете снять пометку с флеш-плеера или скинов, если вы не планируете их устанавливать. Эти действия будет записаны в файл Opera-10.51.ini. Далее, при запуске с ключом /S инсталлятор подцепит этот файл, и не установит того, что не было выбрано в режиме генератора ответов. Ключ /G не совместим с другими ключами инсталлятора.
Код:
Opera-10.51.exe /D=E:\opera
Ключ указывает, в какую папку ему устанавливать приложение. Совместим и целесообразен к использованию с /S:
Код:
Opera-10.51.exe /S /D=E:\opera
Готовую сборку с последней официальной версией 10.63, созданную на основе этого скрипта, можно
забрать здесь
Тихая установка Opera 11